Key.addListener()

可用性

Flash Player 6。

用法

Key.addListener (newListener)

参数

newListener 具有方法 onKeyDown 和 onKeyUp 的对象。

返回

无。

说明

方法；注册一个对象以接收 onKeyDown 和 onKeyUp 通知。当按下或释放按键时，不管输入焦点情况如何，所有用 addListener() 注册的侦听对象都将调用其 onKeyDown 方法或 onKeyUp 方法。可以有多个对象侦听键盘通知。如果已经注册了侦听器 newListener，则不会发生任何
更改。

示例

以下示例创建一个新的侦听器对象，并为 onKeyDown 和 onKeyUp 定义一个函数。最后一行使用 addListener() 向 Key 对象注册该侦听器，以使该对象可接收按下和释放按键事件的通知。

myListener = new Object();
myListener.onKeyDown = function () {
  trace ("You pressed a key.");
}
myListener.onKeyUp = function () {
  trace ("You released a key.");
}
Key.addListener(myListener);

以下示例将快捷键 Control+7 分配给实例名称为 myButton 的按钮，并将与该快捷键有关的信息提供给屏幕读取器（请参见 _accProps）。在此示例中，在您按下 Control+7 组合键时，myOnPress 函数在“输出”面板中显示文本“hello”；您可以在自己的文件中创建更具意义的函数。

function myOnPress() {
  trace( "hello" );
}

function myOnKeyDown() {
  if (Key.isDown(Key.CONTROL) && Key.getCode() == 55) // 55 是 7 的键控代码
  {
    Selection.setFocus( myButton );
    myButton.onPress();
  }
}

var myListener = new Object();
myListener.onKeyDown = myOnKeyDown;
Key.addListener(myListener);

myButton.onPress = myOnPress;
myButton._accProps.shortcut = "Ctrl+F"
Accessibility.updateProperties();

另请参见

Key.getCode()、Key.isDown()、Key.onKeyDown、Key.onKeyUp、Key.removeListener()