IIsMimeMap (ADSI)

可以使用 IIsMimeMap 对象设置 Web 服务器使用的通过继承得到的多用途 Internet 邮件扩展 (MIME) 映射。

IIsMimeMap 对象是一个 ADSI 对象，而不是 ADSI 容器对象。

ADsPath

IIS://MachineName/MIMEMAP

其中，MachineName 可以是任何名称或 LocalHost。

语法

varReturn= object.Method

参数

varReturn

从该方法接收返回值的变量。

object

包含 IIsMimeMap 对象的变量（通常作为上一个 GetObject 操作的结果）。

Method

选定的对象方法。

属性

配置数据库属性

方法

代码示例

<% 
  Dim MimeMapObj, aMimeMap, MMType, MMExtension, i, aMimeMapNew() 
  Const ADS_PROPERTY_UPDATE = 2 
'获取 MimeMap 对象。 
  Set MimeMapObj = GetObject("IIS://LocalHost/MimeMap") 
'从 MimeMap 属性中获取映射。
  aMimeMap = MimeMapObj.GetEx("MimeMap") 
' 显示映射。
  ShowMM(MimeMapObj) 
' 添加新映射。
  i = UBound(aMimeMap) + 1 
  Redim Preserve aMimeMap(i) 
  Set aMimeMap(i) = CreateObject("MimeMap") 
  aMimeMap(i).Extension = ".jnq" 
  aMimeMap(i).MimeType = "junque/my-junque" 
  MimeMapObj.PutEx ADS_PROPERTY_UPDATE, "MimeMap", aMimeMap 
  MimeMapObj.SetInfo 
' 显示映射。
  ShowMM(MimeMapObj) 
'通过复制到新映射数组删除映射。
  i = 0 
  For Each MMItem in aMimeMap 
    If MMItem.Extension <> ".jnq" Then 
      Redim Preserve aMimeMapNew(i) 
      Set aMimeMapNew(i) = CreateObject("MimeMap") 
      aMimeMapNew(i).Extension = MMItem.Extension 
      aMimeMapNew(i).MimeType = MMItem.MimeType 
      i = i + 1 
    End If 
  Next 
  MimeMapObj.PutEx ADS_PROPERTY_UPDATE, "MimeMap", aMimeMapNew 
  MimeMapObj.SetInfo 
' 显示映射。
  ShowMM(MimeMapObj) 
'在表格中显示映射的子例程。
  Sub ShowMM(MMObj) 
  aMM = MMObj.GetEx("MimeMap") 
'设置表格以显示映射。
  Response.Write "<HR><TABLE BORDER><CAPTION><B>MIME Maps</B></CAPTION>" 
  Response.Write "<TR><TH>Type</TH><TH>Extension</TH>" 
'在表格中显示映射。
  For Each MM in aMM 
    Response.Write "<TR><TD>" & MM.MimeType & "</TD>" 
    Response.Write "<TD>" & MM.Extension & "</TD></TR>" 
  Next 
  Response.Write "</TABLE>" 
  End Sub 
%> 

© 1997-2003 Microsoft Corporation。保留所有权利。