IIsComputer.EnumBackups (ADSI)

可以使用 IIsComputer (ADSI) 对象的 EnumBackups 方法来枚举存储在一个或多个位置的配置数据库备份，检索每个备份的位置、版本号及日期。

语法

IIsComputer.EnumBackups BkupLocIn, IndexIn, BkupVerOut, BkupLocOut, BkupDateTimeOut

参数

BkupLocIn

指定备份位置的字符串（最多为 100 个字符）。如果指定一个空字符串，则将搜索所有的备份位置。

IndexIn

指定要枚举的备份索引。在 0 处开始索引，然后逐步加 1 直到返回 MD_ERROR_DATA_NOT_FOUND。

BkupVerOut

检索所枚举的备份的版本号。

BkupLocOut

接收所枚举备份的备份位置。

BkupDateTimeOut

接收备份的日期和时间，使用协调通用时间 (UTC)，即原来的 GMT（格林威治标准时间）。

代码示例

<%@ LANGUAGE=VBScript %> 
<SCRIPT LANGUAGE = "JScript" RUNAT = SERVER> 
  var TempDate = new Date(); 
  TempDif = TempDate.getTimezoneOffset(); 
  Session("sTempDif") = TempDif; 
</SCRIPT> 
<% 
  Dim CompObj, Index, Version, Location, GMTDate, LocDate, MinDif 
  MinDif = Session("sTempDif") 
  On Error Resume Next 
  Set CompObj = GetObject("IIS://LocalHost") 
  Index = 0 
' 重复直到方法返回错误。 
  Do While True 
    ' 空位置输入字符串表示枚举所有位置。 
    CompObj.EnumBackups "", Index, Version, Location, GMTDate 
    If Err.Number <> 0 Then 
      '如果返回错误，则不再枚举备份。
      Exit Do 
    End If 
    Response.Write Version & ", " 
    Response.Write Location & ", " 
    Response.Write GMTDate & ", "
    '转换到服务器本地日期和时间。
    LocDate = DateAdd("n", (-MinDif), GMTDate) 
    Response.Write "(" & LocDate & ")" 
    Response.Write "<BR>" 
    Index = Index + 1 
  Loop 
%> 

© 1997-2003 Microsoft Corporation。保留所有权利。